File zum Schreiben oeffnen ($d8c6)

Einsprung von $9759:

9773: A5 F4     LDA $F4          b7=1: Jokerflag gesetzt ?
9775: 29 80     AND #$80         (z.B.: SAVE"@:BEISP*",ga)
9777: AA        TAX
9778: D0 14     BNE $978E        ja, ==>
977A: A9 20     LDA #$20         b5=1: File nicht geschlossen ?
977C: 24 F4     BIT $F4
977E: F0 06     BEQ $9786        nein ==>

[Ja: In diesem Fall existiert bereits ein File mit dem geforderten Namen,
 das aber nicht ordnungsgemaess geschlosen worden ist. Dieses muss erst
 geloescht werden, bevor das neue File angelegt wird.]

9780: 20 3B 87  JSR $873B        altes File als geloescht kennzeichnen
9783: 4C 90 98  JMP $9890        neues File anlegen

Einsprung von $977E:

9786: AD 97 02  LDA $0297        File bereits vorhanden (Tracknummer >0) ?
9789: D0 03     BNE $978E        ja, ==>
978B: 4C 90 98  JMP $9890        neues File anlegen

Einsprung von $9778, $9789:

978E: AD 00 02  LDA $0200        1. Zeichen aus Befehlszeile holen
9791: C9 40     CMP #$40         SAVE & REPLACE ?
9793: F0 0D     BEQ $97A2        ja, ==>
9795: 8A        TXA              Jokerflag gesetzt (SAVE"BEISP*",ga) ?
9796: D0 05     BNE $979D        ja, (Fehler) ==>

9798: A9 63     LDA #$63         63, FILE EXISTS
979A: 4C 7C 80  JMP $807C

Einsprung von $9796:

979D: A9 33     LDA #$33         33, SYNTAX ERROR
979F: 4C 7C 80  JMP $807C

DOS 4

    Previous Page / Next Page